***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 16, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJW5N10-AU  D  G  S
rg     G    1t    1
m1     2     1    3    3    dmos    L=1u   W=1u
.model dmos nmos ( 
+vto = 2.4 		
+kp = 6		
+tnom = 25
+level = 3		gamma = 1.45	;kappa = 0.2
+rd = 2e-2		)   
cgs	1t	 3	1.24n	ic = 0
rd	 D	 4	2e-2	tc=3e-2
dds	 3	 4	dds
.model dds d (
+bv = 110		ibv = 0.25e-6		tbv1 = 0.91e-3
+m = 0.1971		cjo=393p		vj=0.06487
+is = 2.9e-13		n = 1.009		rs = 6e-3		trs1 = 8e-3)
e1	1 3 table { v(1t, S) } 
+ ((0   , 0   )
+  (1.00, 0.50)
+  (1.50, 1.00)
+  (2.00, 1.17)
+  (3.00, 2.17)
+  (4.00, 3.17)
+  (4.50, 4.50)
+  (5.00, 5.30)
+  (10.0, 5.95)) 
dbody   3   D    dbody
*gds D S value = {1e-2*(temp-25)*limit((v(G,S)-1),0,1.5)*limit(v(D,S),0,1)}
.model   dbody    d(
+is = 2.9e-13		n = 1.009		rs = 6e-3		trs1 = 8e-3	
+tt = 100n		vj = 0.8		eg = 1.146 )
ra      4    2    1.5e-2  tc=1e-2
rs      3    5    7e-3
ls      5    S   0.0001n
m2      1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    4    431p ic=0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
